query-4ad9d144f741536f0a4b5395dfb08d42

rq turtle/ttl

Deportes en los que Perú tiene más medallas en los Olympic Games Deportes en los que Perú tiene más medallas en los Olympic Games Deportes en los que Perú tiene más medallas en los Olympic Games Sportwedstrijden waarin Peru de meeste medailles heeft behaald op Olympic Games

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT
  ?deporte
  ?deporteLabel
  (COUNT(?deporte) AS ?count)
{
  # Campeones en los Juegos Olímpicos

  ?juego_olímpico
    wdt:P31/wdt:P279* wd:Q18536594;
    wdt:P641 ?deporte;
    p:P1346 ?declaración.

  ?declaración
    ps:P1346 ?campeón;
    pq:P642 ?medalla.

  # El valor de la variable "medalla" debe ser un valor que exprese posición en los 3 primeros puestos

  VALUES ?medalla {
    # Primer puesto
    wd:Q15243387
    wd:Q20882667
    # Segundo puesto
    wd:Q15889641
    wd:Q20882668
    # Tercer puesto
    wd:Q15889643
    wd:Q20882669
  }

  # El campeón debe ser un peruano

  {?campeón wdt:P27 wd:Q419 }
  UNION
  {?campeón wdt:P19/wdt:P131* wd:Q419 }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?deporte ?deporteLabel

Query found at

• https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/Peru
• https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/Peru/de
• https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/Peru/es
• https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/Peru/nl