query-48680cd528c76cdcac15edcf9f29739e

rq turtle/ttl

SELECT MAPS/MAPS SERIES BY DATE OF PUBLICATION IN ASSECNDING ORDER SELECT DISTINCT ?map ?mapLabel ?mapDescription ?width ?width_unitLabel ?height ?height_unitLabel ?scale ?series ?seriesLabel ?publisher ?publisherLabel ?publicationDate ?placepfPublication ?placepfPublicationLabel ?depicts ?depictsLabel ?mainSubject ?mainSubjectLabel ?language ?languageLabel ?countryOfOrigin ?countryOfOriginLabel ?oclc_url ?map_url WHERE { ?map wdt:P31 wd:Q4006 . OPTIONAL {?map wdt:P953 ?map_url} . ?map wdt:P123 ?publisher ; wdt:P577 ?publicationDate ; wdt:P291 ?placepfPublication ; wdt:P921 ?mainSubject ; p:P2049 ?width_stmnode . #?map wdt:P5008 wd:Q73644758 . # CHANGE PROJECT FOCUS LIST HERE ?width_stmnode psn:P2049 ?width_valuenode . ?width_valuenode wikibase:quantityAmount ?width . ?width_valuenode wikibase:quantityUnit ?width_unit . ?map p:P2048 ?height_stmnode . ?height_stmnode psn:P2048 ?height_valuenode . ?height_valuenode wikibase:quantityAmount ?height . ?height_valuenode wikibase:quantityUnit ?height_unit . ?map wdt:P1752 ?scale ; wdt:P407 ?language ; wdt:P495 ?countryOfOrigin ; OPTIONAL {?map wdt:P243 ?oclcControlNumber } . OPTIONAL {?map wdt:P179 ?series ; wdt:P180 ?depicts } . BIND(URI(CONCAT("https://www.worldcat.org/oclc/",?oclcControlNumber)) AS ?oclc_url) #FILTER(?countryOfOrigin != wd:Q30) SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } }ORDER BY ASC (?publicationDate)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX psn: <http://www.wikidata.org/prop/statement/value-normalized/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# SELECT MAPS/MAPS SERIES BY DATE OF PUBLICATION IN ASSECNDING ORDER
SELECT DISTINCT ?map ?mapLabel 
?mapDescription ?width ?width_unitLabel ?height ?height_unitLabel ?scale ?series ?seriesLabel
?publisher ?publisherLabel ?publicationDate ?placepfPublication 
?placepfPublicationLabel ?depicts ?depictsLabel ?mainSubject ?mainSubjectLabel ?language
?languageLabel ?countryOfOrigin ?countryOfOriginLabel ?oclc_url ?map_url
WHERE
{
 ?map wdt:P31 wd:Q4006 . 
 OPTIONAL {?map wdt:P953 ?map_url} .
 ?map wdt:P123 ?publisher ;
      wdt:P577 ?publicationDate ;
      wdt:P291 ?placepfPublication ;
      wdt:P921 ?mainSubject ;
      p:P2049 ?width_stmnode .
 #?map wdt:P5008 wd:Q73644758 . # CHANGE PROJECT FOCUS LIST HERE
 ?width_stmnode psn:P2049 ?width_valuenode .
 ?width_valuenode wikibase:quantityAmount ?width .
 ?width_valuenode wikibase:quantityUnit ?width_unit . 
 ?map p:P2048 ?height_stmnode .
 ?height_stmnode psn:P2048 ?height_valuenode .
 ?height_valuenode wikibase:quantityAmount ?height .
 ?height_valuenode wikibase:quantityUnit ?height_unit .
 ?map wdt:P1752 ?scale ;
      wdt:P407 ?language ;
      wdt:P495 ?countryOfOrigin ;
   OPTIONAL {?map wdt:P243 ?oclcControlNumber } .
   OPTIONAL {?map wdt:P179 ?series ;
                  wdt:P180 ?depicts } . 
 BIND(URI(CONCAT("https://www.worldcat.org/oclc/",?oclcControlNumber)) AS ?oclc_url)
 #FILTER(?countryOfOrigin != wd:Q30) 
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}ORDER BY ASC (?publicationDate)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_PCC_Wikidata_Pilot/UNLV