query-46b3a6b11c8904a8e36929f53873923a

rq turtle/ttl

Liste des installations comprenant un terrain de polo-vélo en France SELECT ?installation ?installationLabel ?numéro ?nomRESinstallation (GROUP_CONCAT(?noméquipement; separator=" ; ") AS ?nomséquipements) # liste des noms des équipements, séparés par des points-virgules WHERE { VALUES ?code { "609" }. # choix du type d'équipement sportif ?typeéquipement p:P528 [ps:P528 ?code; # code du type d'équipement pq:P2868 wd:Q121252873; # type d'équipement sportif prov:wasDerivedFrom [ pr:P248 wd:Q115755558 ] # enregistrement au Recensement des équipements sportifs ].

?installation p:P912 [ps:P912 ?typeéquipement; # présence d'un équipement de ce type pq:P2561 ?noméquipement; # nom de l'équipement ]. ?installation p:P11840 [ps:P11840 ?numéro; # numéro de l'installation dans le Recensement des équipements sportifs pq:P1810 ?nomRESinstallation; # nom de l'installation dans le Recensement des équipements sportifs prov:wasDerivedFrom [ pr:P248 wd:Q115755558; pr:P5017 ?miseàjour ] # date de mise à jour dans le Recensement des équipements sportifs ].
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". ?installation rdfs:label ?installationLabel . # libellé de l'installation ?typeéquipement rdfs:label ?typeéquipementLabel . # libellé du type d'équipement }
}GROUP BY ?installation ?installationLabel ?numéro ?nomRESinstallation ORDER BY ?installationLabel

Use at

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Liste des installations comprenant un terrain de polo-vélo en France
SELECT ?installation ?installationLabel ?numéro ?nomRESinstallation
(GROUP_CONCAT(?noméquipement; separator=" ; ") AS ?nomséquipements) # liste des noms des équipements, séparés par des points-virgules
WHERE {
  VALUES ?code { "609" }. # choix du type d'équipement sportif
  ?typeéquipement p:P528 [ps:P528 ?code; # code du type d'équipement
                        pq:P2868 wd:Q121252873; # type d'équipement sportif
                        prov:wasDerivedFrom [ pr:P248 wd:Q115755558 ] # enregistrement au Recensement des équipements sportifs
                ].

  ?installation p:P912 [ps:P912 ?typeéquipement; # présence d'un équipement de ce type
                                pq:P2561 ?noméquipement; # nom de l'équipement
                ].
  ?installation p:P11840 [ps:P11840 ?numéro; # numéro de l'installation dans le Recensement des équipements sportifs
                        pq:P1810 ?nomRESinstallation; # nom de l'installation dans le Recensement des équipements sportifs
                        prov:wasDerivedFrom [ pr:P248 wd:Q115755558; pr:P5017 ?miseàjour ] # date de mise à jour dans le Recensement des équipements sportifs
                ].  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
                          ?installation rdfs:label ?installationLabel . # libellé de l'installation
                          ?typeéquipement rdfs:label ?typeéquipementLabel . # libellé du type d'équipement
                          }                        
}GROUP BY ?installation ?installationLabel ?numéro ?nomRESinstallation
ORDER BY ?installationLabel

Query found at

graph TD classDef projected fill:lightgreen; classDef literal fill:orange; classDef iri fill:yellow; v2("?code") v5("?installation"):::projected v1("?installationLabel"):::projected v8("?miseàjour") v7("?nomRESinstallation"):::projected v10("?nomséquipements") v4("?noméquipement"):::projected v6("?numéro"):::projected v3("?typeéquipement") v9("?typeéquipementLabel") a1((" ")) a2((" ")) a3((" ")) a4((" ")) a5((" ")) c18(["fr"]):::literal c3(["wd:Q121252873"]):::iri c5(["wd:Q115755558"]):::iri c16(["bd:serviceParam"]):::iri bind0[/VALUES ?code/] bind0-->v2 bind00(["609"]) bind00 --> bind0 a1 --"p:statement/P528"--> v2 a1 --"p:qualifier/P2868"--> c3 a2 --"p:reference/P248"--> c5 a1 --"prov:wasDerivedFrom"--> a2 v3 --"p:P528"--> a1 a3 --"p:statement/P912"--> v3 a3 --"p:qualifier/P2561"--> v4 v5 --"p:P912"--> a3 a4 --"p:statement/P11840"--> v6 a4 --"p:qualifier/P1810"--> v7 a5 --"p:reference/P248"--> c5 a5 --"p:reference/P5017"--> v8 a4 --"prov:wasDerivedFrom"--> a5 v5 --"p:P11840"--> a4 subgraph s1["http://wikiba.se/ontology#label"] style s1 stroke-width:4px; c16 --"wikibase:language"--> c18 v5 --"rdfs:label"--> v1 v3 --"rdfs:label"--> v9 end bind2[/"?noméquipement"/] v4 --o bind2 bind2 --as--o v10