query-439b9b6ec0c205be2dac546d54a96c47

rq turtle/ttl

TODO

Use at

• https://query.wikidata.org/sparql

PREFIX wd: <http://www.wikidata.org/entity/>
SELECT DISTINCT ?prop WHERE {
  ?work ?prop wd:Q4233718. # anon must be the value
  BIND(STR(?prop) as ?propUri). # turn it into a URI
  FILTER(
    # Uncomment these lines to decide where we are looking for "anonymous"
    false
      || STRSTARTS(?propUri, "http://www.wikidata.org/prop/direct")    # in statement values
#       || STRSTARTS(?propUri, "http://www.wikidata.org/prop/qualifier") # in qualifiers
#       || STRSTARTS(?propUri, "http://www.wikidata.org/prop/reference") # in references
  ).

  ## Properties to ignore (acceptable uses) ##
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P31"). # instance of
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P279"). # subclass of
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P1889"). # different from
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P5137"). # item for this sense
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P301"). # category's main topic
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P138"). # named after (only 1 item (Q51213808), which is indeed named after "anonymous")
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P4967"). # prerequisite (only 1 item (Q60628769), which has anonymity as a needed condition)
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P1552"). # has quality (only 1 item, which uses this right)
  FILTER(?propUri != "http://www.wikidata.org/prop/direct/P1535"). # used by (only 2 items, both use this right)
}
LIMIT 100

Query found at

• https://www.wikidata.org/wiki/User:SixTwoEight/Properties_with_anonymous