query-3f42c4d347494a838e727e0614bb71de

rq turtle/ttl

Czech settlements in radius of a specific distance from the point

Česká sídla (vesnice, města) v určité vzdálenosti od bodu

SELECT ?place ?location ?centerpointLoc ?placeLabel ?distance ?article ?sitelink WHERE { wd:Q2180733 wdt:P625 ?centerpointLoc . # wd stays for point (settlement) from which the radius goes - proměnná za wd je položkou (sídlem) dle Wikidat, od kterého se v učité vzdálenosti vypíší sídla SERVICE wikibase:around { ?place wdt:P625 ?location . bd:serviceParam wikibase:center ?centerpointLoc . bd:serviceParam wikibase:radius "35" . # set number of a diameter in km - číslo urči kilometrickou vzdálenost od bodu bd:serviceParam wikibase:distance ?distance . } ?place wdt:P2788 ?P2788. optional { ?article1 schema:about ?place ; schema:isPartOf https://cs.wikipedia.org/ . ?sitelink1 ^schema:name ?article1 .} SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],cs". } OPTIONAL {?place wdt:P131 ?P131 . ?article2 schema:about ?P131 ; schema:isPartOf https://cs.wikipedia.org/ . ?sitelink2 ^schema:name ?article2 .} bind(coalesce(?sitelink1, ?sitelink2) as ?sitelink) bind(coalesce(?article1, ?article2) as ?article)

}

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Czech settlements in radius of a specific distance from the point
# Česká sídla (vesnice, města) v určité vzdálenosti od bodu
SELECT ?place ?location ?centerpointLoc ?placeLabel ?distance ?article ?sitelink WHERE {
   wd:Q2180733 wdt:P625 ?centerpointLoc . # wd stays for point (settlement) from which the radius goes - proměnná za wd je položkou (sídlem) dle Wikidat, od kterého se v učité vzdálenosti vypíší sídla
   SERVICE wikibase:around { 
     ?place wdt:P625 ?location . 
     bd:serviceParam wikibase:center ?centerpointLoc .
     bd:serviceParam wikibase:radius "35" . # set number of a diameter in km - číslo urči kilometrickou vzdálenost od bodu
     bd:serviceParam wikibase:distance ?distance .
     } 
  ?place wdt:P2788 ?P2788.
  optional { ?article1 schema:about ?place ;
                      schema:isPartOf <https://cs.wikipedia.org/> . 
             ?sitelink1 ^schema:name ?article1 .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],cs". }
  OPTIONAL {?place wdt:P131 ?P131 .
            ?article2 schema:about ?P131 ;
                     schema:isPartOf <https://cs.wikipedia.org/> . 
            ?sitelink2 ^schema:name ?article2 .}
  bind(coalesce(?sitelink1, ?sitelink2) as ?sitelink)
  bind(coalesce(?article1, ?article2) as ?article)

}

Query found at

• https://www.wikidata.org/wiki/User:Juandev/Queries
• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2019/04