query-3f36e457eddc6c311b042f6009e6ec9e

rq turtle/ttl

Tempo di arrivo sulla ISS

SELECT ?item ?itemLabel ?launchdate ?dockdate ?flyingtime WHERE { ?item wdt:P31 wd:Q752783 . #istanza di Volo Spaziale

# Select the vehicles docked to the ISS ?item p:P793 [ #riferimento alla dichiarazione "evento chiave" ps:P793 wd:Q557450 ; #seleziona l'evento del docking pq:P276 wd:Q25271 #luogo = ISS ].

# Launch date
OPTIONAL { ?item p:P793 [ #riferimento alla dichiarazione "evento chiave" ps:P793 wd:Q797476; #seleziona l'evento del "lancio del razzo vettore" pq:P585 ?launchdate #estrae il qualificatore con la "data" dell'evento di lancio ]. }

# Docking date OPTIONAL { ?item p:P793 [ #riferimento alla dichiarazione "evento chiave" ps:P793 wd:Q557450 ; #seleziona l'evento del docking pq:P580 ?dockdate #data di inizio del docking, i.e. dell'arrivo sulla ISS ]. }

BIND(?dockdate-?launchdate AS ?flyingtime)

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } } ORDER BY ?launchdate

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#Tempo di arrivo sulla ISS

SELECT ?item ?itemLabel ?launchdate ?dockdate ?flyingtime
WHERE
{
  ?item wdt:P31 wd:Q752783 .        #istanza di Volo Spaziale

  # Select the vehicles docked to the ISS
  ?item  p:P793 [                  #riferimento alla dichiarazione "evento chiave"
           ps:P793 wd:Q557450 ;    #seleziona l'evento del docking
           pq:P276 wd:Q25271       #luogo = ISS
          ].

  # Launch date  
  OPTIONAL {
  ?item p:P793 [                  #riferimento alla dichiarazione "evento chiave"
           ps:P793 wd:Q797476;    #seleziona l'evento del "lancio del razzo vettore"
           pq:P585 ?launchdate    #estrae il qualificatore con la "data" dell'evento di lancio
          ].
  }

  # Docking date
  OPTIONAL {
  ?item  p:P793 [                  #riferimento alla dichiarazione "evento chiave"
           ps:P793 wd:Q557450 ;    #seleziona l'evento del docking
           pq:P580 ?dockdate       #data di inizio del docking, i.e. dell'arrivo sulla ISS
          ].
  }

  BIND(?dockdate-?launchdate AS ?flyingtime)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?launchdate

Query found at

• https://www.wikidata.org/wiki/User:FabC