query-3edead6ba7cfaae1c9ad150472a2ae32

rq turtle/ttl

Propertiesmain subject (P921)taxon rank (P105)maintained by WikiProject (P6104)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#title: Works about predation and at least two species, at least one of which is in scope
#defaultView:Table

PREFIX target: <http://www.wikidata.org/entity/Q170430> 

SELECT ?count # (CONCAT("/topics/Q202864,", SUBSTR(STR(?topic), 32)) AS ?countUrl)
       ?topic ?topicLabel # (CONCAT("/topic/", SUBSTR(STR(?topic), 32)) AS ?topicUrl)
       ?topic1 ?topic1Label # (CONCAT("/topic1/", SUBSTR(STR(?topic), 32)) AS ?topic1Url)
       ?example_work ?example_workLabel # (CONCAT("/work/", SUBSTR(STR(?example_work), 32)) AS ?example_workUrl)
WHERE {
  # Label the results
   {
  SELECT DISTINCT ?topic ?topic1 (COUNT(?work) AS ?count) (SAMPLE(?work) AS ?example_work) WHERE {
    # Find works for the specific queried topic
      ?work wdt:P921 target: .

    # Find co-occuring topics
    ?work wdt:P921 ?topic .
    ?work wdt:P921 ?topic1 .

    # Filter for species
    ?topic wdt:P105 wd:Q7432 .
    ?topic1 wdt:P105 wd:Q7432 .

    # Filter for topics within scope of WikiProject Invasion biology
    ?topic wdt:P6104 wd:Q56241615 .

    # Avoid listing the queried topic
      FILTER (target: != ?topic)
      FILTER (target: != ?topic1)
      FILTER (?topic != ?topic1)
}
  GROUP BY ?topic ?topic1
}  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Invasion_biology