query-3befc2e1428288627bda2ec4a0b0e0c2

rq turtle/ttl

TODO

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Table;
#------------------------------------------------------------------------------------
# opera singers who are sopranos with article in English Wikipedia and no data in voice type
#------------------------------------------------------------------------------------
SELECT DISTINCT ?item ?itemLabel ?desc_en ?voice_typeLabel ?maybe_sopran ?article_en ?article_de  
WHERE {
  ?item wdt:P31 wd:Q5.                # is human
  ?item wdt:P106 wd:Q2865819.         # and occupatition is opera singer
  MINUS { ?item wdt:P412  [] }        # and has no data in voice type

  ?item schema:description ?desc_en . filter (lang(?desc_en) = "en").            # get english description
  BIND(IF(REGEX(STR(?desc_en), "sopran","i"),"sopran"," - ") AS ?maybe_sopran)   # check english description for "sopran"
  FILTER(CONTAINS(?maybe_sopran, 'sopran')) .                                    # filter only sopran

  ?article_en schema:about ?item.
  ?article_en schema:isPartOf <https://en.wikipedia.org/>.    # article in English

  OPTIONAL {
    ?article_de schema:about ?item.
    ?article_de schema:isPartOf <https://de.wikipedia.org/>.    # article in German
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
order by ?itemLabel

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query