query-3053aa0846defdedd289b0bad1f491ff

rq turtle/ttl

PropertiesInChIKey (P235)

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX wp: <http://vocabularies.wikipathways.org/wp#>

SELECT DISTINCT ?metabolite ?wikidata ?inchikey ?charge WHERE {
   {
  SELECT ?metabolite ?wikidata WHERE {
    SERVICE <http://sparql.wikipathways.org/sparql> {
      ?metabolite a wp:Metabolite ;
                  wp:bdbWikidata ?wikidata .
    }
  }
}  ?wikidata wdt:P235 ?inchikey .
  bind(
    if(substr(?inchikey,27) = "N", "0"^^xsd:integer, 
      if(substr(?inchikey,27) = "M", "-1"^^xsd:integer, 
        if(substr(?inchikey,27) = "O", "+1"^^xsd:integer,
          if(substr(?inchikey,27) = "L", "-2"^^xsd:integer,
            if(substr(?inchikey,27) = "P", "+2"^^xsd:integer,
              if(substr(?inchikey,27) = "K", "-3"^^xsd:integer,
                if(substr(?inchikey,27) = "J", "-4"^^xsd:integer,
                  if(substr(?inchikey,27) = "I", "-5"^^xsd:integer,
                    if(substr(?inchikey,27) = "F", "-8"^^xsd:integer,
                      "999"^^xsd:integer # ERROR
                    )
                  )
                )
              )
            )
          )
        )
      )
    )
    as ?charge
  )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Query found at

• https://www.wikidata.org/wiki/User:Pathwaybot/query_examples