query-2e8ba890f5d5cceae7ffc5caec7a123d

rq turtle/ttl

Propertiesinstance of (P31)position held (P39)spouse (P26)start time (P580)end time (P582)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT 
?president ?presidentLabel 
?termStart ?termEnd
?spouse 
?relationshipStart ?relationshipEnd 
WHERE {

   ?president wdt:P31 wd:Q5 .

   ?president                p:P39     ?position_held_statement .
   ?position_held_statement ps:P39   wd:Q11696 .
   ?position_held_statement pq:P580    ?termStart .

   # current presiden will always miss it
   OPTIONAL {   
     ?position_held_statement pq:P582  ?termEnd
   } 

   # spouse is optional
   OPTIONAL {
      ?president             p:P26     ?spouseStatement .
      ?spouseStatement      ps:P26     ?spouse .
      ?spouseStatement      pq:P580    ?relationshipStart .

      # current spouse will always miss it
      OPTIONAL {   
        ?spouseStatement    pq:P582    ?relationshipEnd
      }
   }

   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

 } ORDER BY ?termStart ?relationshipStart

Query found at

• https://www.wikidata.org/wiki/User:D1gggg/Wikidata_model_and_SPARQL