query-245c3ef3f9565ec154d89f09917ea901

rq turtle/ttl

Propertiesmaintained by WikiProject (P6104)author name string (P2093)

Use at

• https://query.wikidata.org/sparql

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT
  # Number of works on the topic with the author name string
  ?count

  # Number of works with the author name string
  ?count1

  # Author as a string
  ?authorstring

  # Build URL to the Author disambiguator tool
  (CONCAT(
      'https://tools.wmflabs.org/author-disambiguator/names_oauth.php?name=',
      ENCODE_FOR_URI(?authorstring)) AS ?resolver_url)
WHERE {
   {
  SELECT
    (COUNT(DISTINCT ?work) AS ?count)
    (COUNT(DISTINCT ?work1) AS ?count1)
    ?authorstring
  WHERE {
     {
  SELECT DISTINCT ?work ?authorstring WHERE {
    SERVICE bd:sample { ?work wdt:P6104 wd:Q56241615 . bd:serviceParam bd:sample.limit 100000 }   
    ?work wdt:P2093 ?authorstring .
  }
  LIMIT 10000
}    ?work1 wdt:P2093 ?authorstring .
  }
  GROUP BY ?authorstring
}}
ORDER BY DESC(?count) DESC(?count1)
LIMIT 200

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Invasion_biology