query-23f776d0ae6cd69836437d01441f9404

rq turtle/ttl

GitHub users who co-authored scholarly publications

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# tool: scholia
#defaultView:Graph
SELECT ?author1 ?author1Label ?rgb ?author2 ?author2Label
WHERE {
   {
  # Limit the number of coauthors
  SELECT DISTINCT ?author2 ?author1  (COUNT(?work) AS ?count2)  WHERE {
     {
  # Limit the number of authors
  SELECT (COUNT(?work) AS ?count1) ?author1 ?work WHERE {
    ?work wdt:P50 ?author1 .
    ?author1 wdt:P2037 ?githubuser1 .
  }
  GROUP BY ?author1 ?work
  ORDER BY DESC(?count1)
  LIMIT 10000
}    ?work wdt:P50 ?author1 , ?author2 .
    ?author2 wdt:P2037 ?githubuser2 .
    FILTER (?author1 != ?author2) 
  }
  GROUP BY ?author2 ?author1 
  ORDER BY DESC(?count2)
  LIMIT 10000
}  OPTIONAL { ?author1 wdt:P21 ?gender1 . }
  BIND( IF(?gender1 = wd:Q6581097, "3182BD", "E6550D") AS ?rgb)
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,fr,de,ru,es,zh,jp".
  }
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Informatics/Software/Queries