query-20e5deb99866b20b23263e3aec6940ed

rq turtle/ttl

MTA tagjai lekérdezés - mintaértékekel ... ~ 2343 találat ( ?person wdt:P463 wd:Q265058.) SELECT ?person ?mta_id ?pim_id ?mtmt_id ?nas_id ?leopoldina_id ?personLabel ?field_of_workLabel ?genderLabel ?personDescription ?birth ?birthplaceLabel ?death ?commons_gallery ?commons_category WHERE { {
SELECT ?person (SAMPLE(?mta_id) as ?mta_id ) (SAMPLE(?pim_id) as ?pim_id ) (SAMPLE(?mtmt_id) as ?mtmt_id ) (SAMPLE(?nas_id) as ?nas_id) (SAMPLE(?leopoldina_id) as ?leopoldina_id) (SAMPLE(?field_of_work) as ?field_of_work) (SAMPLE(?gender) as ?gender) (SAMPLE(?birth) as ?birth) (SAMPLE(?birthplace) as ?birthplace) (SAMPLE(?death) as ?death) (SAMPLE(?commons_gallery) as ?commons_gallery) (SAMPLE(?commons_category) as ?commons_category) WHERE { # VALUES ?person {wd:Q13423405 wd:Q188128 } ?person wdt:P31 wd:Q5. ?person wdt:P463 wd:Q265058. OPTIONAL { ?person wdt:P3226 ?mta_id. } OPTIONAL { ?person wdt:P569 ?birth .} OPTIONAL { ?person wdt:P19 ?birthplace .} OPTIONAL { ?person wdt:P21 ?gender .}
OPTIONAL { ?person wdt:P570 ?death .} OPTIONAL { ?person wdt:P3973 ?pim_id .} OPTIONAL { ?person wdt:P2492 ?mtmt_id . } OPTIONAL { ?person wdt:P5380 ?nas_id . } OPTIONAL { ?person wdt:P3413 ?leopoldina_id . }
OPTIONAL { ?person wdt:P101 ?field_of_work .} OPTIONAL { ?person wdt:P935 ?commons_gallery .} OPTIONAL { ?person wdt:P373 ?commons_category .}
} group by ?person } SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,es,fr,ro,sk,sr". } } order by xsd:integer(?mta_id)

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# MTA tagjai lekérdezés - mintaértékekel ...  ~ 2343 találat ( ?person wdt:P463 wd:Q265058.)
SELECT ?person ?mta_id
       ?pim_id ?mtmt_id ?nas_id ?leopoldina_id 
       ?personLabel 
       ?field_of_workLabel ?genderLabel
       ?personDescription
       ?birth ?birthplaceLabel 
       ?death 
       ?commons_gallery ?commons_category
WHERE {
{  
SELECT ?person 
       (SAMPLE(?mta_id)  as ?mta_id )
       (SAMPLE(?pim_id)  as ?pim_id )
       (SAMPLE(?mtmt_id) as ?mtmt_id )
       (SAMPLE(?nas_id)  as ?nas_id)
       (SAMPLE(?leopoldina_id) as ?leopoldina_id)
       (SAMPLE(?field_of_work)  as ?field_of_work)
       (SAMPLE(?gender) as ?gender)
       (SAMPLE(?birth)  as ?birth)
       (SAMPLE(?birthplace) as ?birthplace)
       (SAMPLE(?death) as ?death)
       (SAMPLE(?commons_gallery)  as ?commons_gallery) 
       (SAMPLE(?commons_category) as ?commons_category)
WHERE {
 # VALUES ?person {wd:Q13423405 wd:Q188128 }
  ?person wdt:P31   wd:Q5.
  ?person wdt:P463 wd:Q265058.
  OPTIONAL {  ?person wdt:P3226 ?mta_id. }
  OPTIONAL {  ?person wdt:P569  ?birth .}
  OPTIONAL {  ?person wdt:P19   ?birthplace .}
  OPTIONAL {  ?person wdt:P21   ?gender .}   
  OPTIONAL {  ?person wdt:P570  ?death .}
  OPTIONAL {  ?person wdt:P3973 ?pim_id .}
  OPTIONAL {  ?person wdt:P2492 ?mtmt_id . }
  OPTIONAL {  ?person wdt:P5380 ?nas_id . } 
  OPTIONAL {  ?person wdt:P3413 ?leopoldina_id . }   
  OPTIONAL {  ?person wdt:P101  ?field_of_work .}
  OPTIONAL {  ?person wdt:P935  ?commons_gallery .}
  OPTIONAL {  ?person wdt:P373  ?commons_category .}    
}
group by ?person
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,es,fr,ro,sk,sr". }
}
order by xsd:integer(?mta_id)

Query found at

• https://www.wikidata.org/wiki/Wikidata:T%C3%A1rsalg%C3%B3/Archive_3