query-1ce455714dc4ff593c3e44c0734e8e72

rq turtle/ttl

slowenische Namen in Kärnten

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map{"hide":"?rgb"}
#title: find item in Kärnten with de / sl labels
SELECT ?item ?itemLabel ?itemDescription ?labelDe ?labelSl ?coord ?rgb ?layer WHERE {
   {
  SELECT DISTINCT ?item ?labelDe ?labelSl WHERE {
    ?item wdt:P17 wd:Q40 .
    ?item wdt:P625 [] .
    ?item wdt:P131*/wdt:P279* wd:Q37985 .
    OPTIONAL {
      ?item rdfs:label ?labelDe .
      FILTER(LANG(?labelDe) = 'de') .
    }
    OPTIONAL {
      ?item rdfs:label ?labelSl .
      FILTER(LANG(?labelSl) = 'sl') .
    }

  }
}.
  ?item wdt:P31 [] .
  ?item p:P625 ?coordStatement .
  ?coordStatement ps:P625 ?coord .

  bind (if (bound(?labelDe), if (bound(?labelSl), if (?labelDe = ?labelSl, 'ffff00', '00ff00'), 'ff0000'), '000000') as ?rgb ).
  bind (if (bound(?labelDe), if (bound(?labelSl), if (?labelDe = ?labelSl, 'de=sl?', 'de!=sl'), 'no sl'), 'no de') as ?layer ).
  SERVICE wikibase:label { bd:serviceParam wikibase:language '[AUTO_LANGUAGE,de,en]' }
} GROUP BY ?item ?itemLabel ?itemDescription ?labelDe ?labelSl ?coord ?rgb ?layer ORDER BY ASC(?item)

Query found at

• https://www.wikidata.org/wiki/User:Herzi_Pinki/Sparql