query-1b03afc2ca5e484521bc5c727307290f

rq turtle/ttl

(P171)parent taxon (P105)taxon rank

Use at

• https://query.wikidata.org/sparql

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
SELECT DISTINCT ?item ?scientific_name (GROUP_CONCAT(DISTINCT ?common_name; SEPARATOR=", ") AS ?common_English_names)
  ?taxon_id ?genus ?family ?order ?class
WHERE
{

{
  SELECT ?item
  WHERE
  {
    # Select some items for species
    ?item wdt:P31 wd:Q16521 . # ?item is instance of taxan
    ?item wdt:P105 wd:Q7432 . # taxon rank is species
  }
  LIMIT 5
}  ?item wdt:P225 ?scientific_name .
  OPTIONAL
  {
    ?item wdt:P1843 ?common_name .
    FILTER (LANG(?common_name) = 'en')
  }
  OPTIONAL { ?item wdt:P846 ?taxon_id . }

  # Get genus, family, order, class
  ?item wdt:P171+ ?genus .
  ?genus wdt:P105 wd:Q34740 . # taxon rank is genus
  ?genus wdt:P171+ ?family .
  ?family wdt:P105 wd:Q35409. # taxon rank is family
  ?family wdt:P171+ ?order .
  ?order wdt:P105 wd:Q36602 . # taxon rank is order
  OPTIONAL 
  {
    # Not all best rank P171 chains includes a class
    ?order wdt:P171+ ?class .
    ?class wdt:P105 wd:Q37517 . # taxon rank is class
  }
}
GROUP BY ?item ?scientific_name ?taxon_id ?genus ?family ?order ?class

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2022/03