query-1836cdc6d707dee203af93643c26b6f2

rq turtle/ttl

Propertiesinstance of (P31)occupation (P106)formatter URL (P1630)CageMatch worker ID (P2728)start time (P580)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?wrestler ?article (SAMPLE(?link) AS ?link) ?wrestlerLabel
WHERE {
   ?wrestler wdt:P31 wd:Q5 .
   ?wrestler wdt:P106 wd:Q13474373 .
   ?article schema:about ?wrestler .
   ?article schema:inLanguage "en" .
   ?article schema:isPartOf <https://en.wikipedia.org/> .
OPTIONAL { wd:P2728 wdt:P1630 ?url .
           ?wrestler wdt:P2728 ?cgid .
           BIND(IRI(REPLACE(?cgid, '^(.+)$', ?url)) AS ?link).
         }
MINUS {
   ?wrestler p:P106 ?occupation_statement .
   ?occupation_statement ps:P106 wd:Q13474373 .
   ?occupation_statement pq:P580 ?start .
      }
   SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
   }
 } 
GROUP BY ?wrestler ?article ?wrestlerLabel
ORDER BY ?wrestlerLabel

Query found at

• https://www.wikidata.org/wiki/User:HereinTheHague