query-13ff2c7c41333944cf643962c51ff5c6

rq turtle/ttl

(35) Map of deaths from Wuhan pneumonia (COVID-19): birth/death/nationality locationsNo.35 (2020.03.08T1443 created)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# people who died from Wuhan pneumonia (COVID-19)
# querying qualifier
# viewed as map of birth/death/nationality locations, with ?edgeLabel as layer
# also viewable as table and graph
#defaultView:Map{"layer":"?edgeLabel"}
SELECT DISTINCT ?patient ?patientLabel ?image ?birth_date ?disease_start ?death_date ?x ?xLabel ?edgeLabel ?coord
WHERE {
  # ?patient is instance of (P31) human (Q5)
  ?patient wdt:P31 wd:Q5;
  # ?patient's cause of death (P509) is COVID-19 (Q84263196)
           wdt:P509 wd:Q84263196.
  # optional: show ?patient's image (P18) as ?image
  OPTIONAL {?patient wdt:P18 ?image}
  # optional: show ?patient's birth date (P569) as ?birth_date
  OPTIONAL {?patient wdt:P569 ?birth_date}
  # optional: show ?patient's start time (P580) of COVID-19 (Q84263196) as ?disease_start by
  # defining ?patient's "medical condition" (P1050) statement as ?COVID19
  OPTIONAL {?patient p:P1050 ?COVID19.
            # and defining ?COVID19's value as COVID-19 (Q84263196)
            ?COVID19 ps:P1050 wd:Q84263196;
            # and defining ?COVID19's qualifier "start time" (P580) as ?disease_start
                     pq:P580 ?disease_start}
  # optional: show ?patient's death date (P570) as ?death_date
  OPTIONAL {?patient wdt:P570 ?death_date}
  # optional: show ?patient's birth place (P19) or death place (P20) or nationality (P27) or occupation (P106) as ?x
  OPTIONAL {?patient (wdt:P19|wdt:P20|wdt:P27|wdt:P106) ?x
            # optional: show ?x's coordinate location (P625) as ?coord
             OPTIONAL {?x wdt:P625 ?coord}
            # To avoid showing any other relation
            # define ?relation as birth place (P19) or death place (P20) or nationality (P27) or occupation (P106)
             VALUES ?relation {wdt:P19 wdt:P20 wdt:P27 wdt:P106}
            # ?relation is from ?patient to ?x
            ?patient ?relation ?x.
            # get ?relation's property label and allow it to appear on graph edge
            ?edge wikibase:directClaim ?relation;
               a wikibase:Property}
  # show label in auto language as default, and English when no default label exists
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
# order layer by ?edgeLabel
ORDER BY ?edgeLabel

Query found at

• https://www.wikidata.org/wiki/User:Neo-Jay/Query
• https://www.wikidata.org/wiki/User:Neo-Jay/Query/1