query-12ed3dba5e0b2e6719a362e315453b95

rq turtle/ttl

Border checkhas to be checked from both sides of the border to find items outside the foreign border - wrong country, or duplicates outside the own border - wrong country, or duplicates inside the border (save to ignore) on the border but not assigned to both countries ganz Österreich

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map{"hide":"?rgb"}
#title: Border check (with distinct types, less timeout)
SELECT ?item ?itemLabel ?itemDescription ?coord ?anz ?rgb ?layer WHERE {
   {
  SELECT DISTINCT ?item (COUNT(DISTINCT ?country) as ?anz) WHERE {

    ?item wdt:P17 wd:Q215 . #16
    #?item wdt:P131*/wdt:P279* wd:Q980 . # in case of timelimit restrict to sub unit
    ?item wdt:P31 ?isA .
    VALUES ?isA {wd:Q8502 wd:Q16887036 wd:Q2231510 wd:Q10862618 wd:Q35666 wd:Q23397 wd:Q133056} # distinct border related types
    ?item wdt:P625 [] .
    ?item wdt:P17 ?country .
  }
  GROUP BY ?item
}.
  ?item wdt:P31 [] .
  ?item p:P625 ?coordStatement .
  ?coordStatement ps:P625 ?coord .
  BIND(IF(?anz = 1, '60ff60', 'ff0000') AS ?rgb) .
  BIND(IF(?anz = 1, 'inside (single P17)', 'border (multiple P17)') AS ?layer) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language '[AUTO_LANGUAGE,de,en]' }
} GROUP BY ?item ?itemLabel ?itemDescription ?coord ?anz ?rgb ?layer # ORDER BY ASC(?item)

Query found at

• https://www.wikidata.org/wiki/User:Herzi_Pinki/Sparql
• https://www.wikidata.org/wiki/User:Herzi_Pinki/Sparql/Coordinate_Me