query-03144923d261999e252f3bc478f415be

rq turtle/ttl

First commissioning date for naval vessels without service entry

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?date1 WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en-gb,en,mul". }
  {
    SELECT DISTINCT ?item (MIN(?date) as ?date1) WHERE {
      ?item p:P137 ?statement0.
      ?statement0 (ps:P137/(wdt:P279*)) wd:Q172771.
        ?item p:P793 ?statement1.
        ?statement1 (ps:P793/(wdt:P279*)) wd:Q14475832. ?statement1 pq:P585 ?date.
      ?item p:P31 ?statement2.
      ?statement2 (ps:P31/(wdt:P279*)) wd:Q177597.
      MINUS {?item wdt:P729 ?entry}
    }
    GROUP BY ?item
  } 
}

Query found at

• https://www.wikidata.org/wiki/User:Vicarage