query-00360e9ca867c1f54bb218370b404923

rq turtle/ttl

Organizational roles

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX target: <http://www.wikidata.org/entity/Q6053150>

SELECT
  ?persons
  (CONCAT("#scientificeventseries/", SUBSTR(STR(target:), 32), "/organizationalrole/", SUBSTR(STR(?role), 32)) AS ?personsUrl)

  ?role ?roleLabel

  ?example_person ?example_personLabel
  (CONCAT("#author/", SUBSTR(STR(?example_person), 32)) AS ?example_personUrl)

WHERE {
   {
  SELECT  
    (COUNT(?person) AS ?persons)
    ?role 
    (SAMPLE(?person) AS ?example_person)
  WHERE {
    ?event wdt:P179 target: ;
           p:P664 ?organizer_statement .
    ?organizer_statement ps:P664 ?person ;
                         pq:P3831 ?role .
  } 
  GROUP BY ?role
}  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?persons)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Synia:scientificeventseries